GuitarModels/EllipticalNeck.scad

// Include after common.scad

function default_fret_widths(zero_fret_width, other_fret_width) = flatten([[zero_fret_width], [ for (i = [1:$num_frets]) other_fret_width ]]);
function default_neck_width_nut() = ($num_strings-1)*$string_spacing_nut + $string_margin*2;
function default_neck_width_bridge() = ($num_strings-1)*$string_spacing_bridge + $string_margin*2;

function neck_width(mm=0, fret=-9999) = lerp($neck_width_bridge, $neck_width_nut, (fret>-9999) ? (2^(-fret/12)) : (mm/fret_scale_length(0)));
function get_fret_width(fret) = $fret_widths[clamp(0, fret, len($fret_widths)-1)];
function get_fret_height(fret) = sin($fret_angle) * get_fret_width(fret)/2;
function get_max_fret_width() = max($fret_widths);
function get_max_fret_height() = ((1-cos($fret_angle))/(sin($fret_angle))) * get_max_fret_width()/2;

function behind_fret(fret) = fret_scale_length(fret) + get_fret_width(fret)/2;
function after_fret(fret) = fret_scale_length(fret) - get_fret_width(fret)/2;

function string_spacing(y) = lerp($string_spacing_bridge, $string_spacing_nut, y/fret_scale_length(0));
function string_x(i, y) = ($num_strings-i-1)*string_spacing(y) - neck_width(y)/2 + $string_margin;


module strings_reference(string_excess=80) {
	z_nut = $extra_thickness_above_center + $scallop_depth + get_max_fret_height();
	y_nut = fret_scale_length(0);
	z_bridge = z_nut + 4;
	y_bridge = -string_excess;

	for (i = [0:$num_strings-1]) {
		hull() {
			d = $string_diameters_mm[i];
			translate([string_x(i, y_bridge), y_bridge, z_bridge + d/2]) sphere(d=d, $fn=cyl_ld_fn);
			translate([string_x(i, y_nut), y_nut, z_nut + d/2]) sphere(d=d, $fn=cyl_ld_fn);
		}
	}
}

module neck(string_spacing=18, string_margin=4.5, num_strings=3, target_neck_thickness=15, target_neck_thickness_additional_points=[], scallop_depth=3, num_frets=24, fret_width=2.4, filler=false, inlays_only=false, side_markers_only=false, fret_layers_only=false, remove_fret_layers=false, engrave_markers=true) {
	fw2 = fret_width/2;
	neck_length = fret_scale_length(0)+fw2;
	neck_width = (num_strings-1)*string_spacing + string_margin*2;
	module neck_stock() {
		angle_excess = asin((scallop_depth+fw2)/target_neck_thickness);
		a0 = 90-angle_excess;
		a1 = 270+angle_excess;
		rotate([-90, 0, 0])
			if (len(target_neck_thickness_additional_points) < 1) {
				linear_extrude(neck_length)
				polygon([for (i = [0:300]) let(a=lerp(a0, a1, i/300.0)) [neck_width*0.5*sin(a), -target_neck_thickness*cos(a)]]);  // Ellipse
			} else {
				pts = flatten([[[neck_length, target_neck_thickness]], target_neck_thickness_additional_points]);
				echo(pts);
				for (i = [0:len(pts)-2]) {
					pt0 = pts[i];
					pt1 = pts[i+1];
					echo(i, pt0, pt1);
					render() hull() {
						translate([0,0,pt0[0]]) linear_extrude(0.01)
							polygon([for (i = [0:300]) let(a=lerp(a0, a1, i/300.0)) [neck_width*0.5*sin(a), -pt0[1]*cos(a)]]);  // Ellipse
						translate([0,0,pt1[0]]) linear_extrude(0.01)
							polygon([for (i = [0:300]) let(a=lerp(a0, a1, i/300.0)) [neck_width*0.5*sin(a), -pt1[1]*cos(a)]]);  // Ellipse
					}
				}
			}
	}
	module scallop(fret) {
			x0 = fret_scale_length(fret-1) - fw2;
			x1 = fret_scale_length(fret) + fw2;
			xmid = lerp(x0, x1, 0.5);
			// Radius it?
			arc = arc_points([[x0, scallop_depth], [x1, scallop_depth], [xmid, 0]]);
			// echo(arc);
			rotate([90, 0, 90]) linear_extrude(neck_width, center=true) polygon(arc);
	}
	module scallops() {
		for (fret = [0:num_frets]) {
			scallop(fret);
		}
	}
	module fret_bumps() {
		for (fret = [0:num_frets]) {
			translate([0, fret_scale_length(fret), scallop_depth])
				rotate([0, 90]) cylinder(d=fret_width, h = neck_width, center = true, $fn=200);
		}
	}
	module intersect_fret_layers() {
		for (fret = [0:num_frets]) {
			translate([-500, fret_scale_length(fret)-fret_width/2, -500])
				cube([1000, fret_width, 1000]);
		}
		// Some precision error with fret 0 :/
		translate([-500, fret_scale_length(0)-fret_width/2+0.0006, -500])
			cube([1000, fret_width, 1000]);
	}
	module fret_inlays() {
		for (num_text = fret_inlays) {
			fret = num_text[0];
			if (fret <= num_frets) {
				x0 = fret_scale_length(fret-1);
				x1 = fret_scale_length(fret);
				diff = x0 - x1;
				translate([0, lerp(x0, x1, 0.5), -0.5])
					linear_extrude(30)
					text(text = num_text[1], font = JP_Sans_Font, halign = "center", valign = "center", size = clamp(2, diff-fret_width*2-2, 10));
			}
		}
	}
	module fret_side_markers() {
		for (num_text = fret_inlays) {
			fret = num_text[0];
			if (fret <= num_frets) {
				x0 = fret_scale_length(fret-1);
				x1 = fret_scale_length(fret);
				diff = x0 - x1;
				mid = lerp(x0, x1, 0.67);
				rotate([0, -94, 0])
					translate([0, mid, neck_width/2-3])
					linear_extrude(50)
					rotate(-37)
					text(text = str(fret), font = JP_Serif_Font, halign = "right", valign = "center", size = 5);
			}
		}
	}

	module carved_stock() {
		render() difference() {
			neck_stock();
			scallops();
			scallop(num_frets+1);
			// Chop off anything above the frets
			translate([-neck_width, 0, scallop_depth]) cube([neck_width*2, $guitar_scale_length_mm*3, target_neck_thickness*3]);
			// Reduce rest of the body to 0
			translate([-neck_width, 0, 0]) cube([neck_width*2, (fret_scale_length(num_frets)+fret_scale_length(num_frets+1))/2, target_neck_thickness*3]);
		}
		intersection() {
			fret_bumps();
			neck_stock();
		}
	}

	if (filler) {  // Somewhat placeholder for now
		difference() {
			neck_stock();
			scallop(25);
			translate([-neck_width, 0, scallop_depth]) cube([neck_width*2, $guitar_scale_length_mm*3, target_neck_thickness*3]);
			translate([-neck_width, 0, 0]) cube([neck_width*2, (fret_scale_length(25)+fret_scale_length(24))/2, target_neck_thickness*3]);
		}
	} else {
		render() intersection() {
			difference() {
				carved_stock();
				if (engrave_markers) {
					fret_inlays();
					fret_side_markers();
				}
				if (remove_fret_layers) intersect_fret_layers();
			}
			if (fret_layers_only || inlays_only || side_markers_only) union() {
				if (fret_layers_only) intersect_fret_layers();
				if (inlays_only) fret_inlays();
				if (side_markers_only) fret_side_markers();
			}
		}
	}
}

module TaperNeck(
	target_neck_thickness_additional_points = [],
	max_scallop_angle = $fret_angle,  // match this to fret_angle for a nice continuous look
	filler = false,
	fret_side_marker_x_angle = -37,
	fret_side_marker_y_angle = -4,
	// $include_colours = [0, 1, 2, 3],  // 0: Base neck/fretboard  1: Frets  2: Inlays  3: Side markers
){
	neck_length = fret_scale_length(0) + get_fret_width(0)/2;

	z0 = $extra_thickness_above_center;  // Deepest scallops hit here, => thinnest top of neck
	z1 = z0 + $scallop_depth;  // Frets protrude from here
	z2 = z1 + get_max_fret_height();  // Nothing above this => thickest top of neck

	module neck_stock() {
		angle_excess = asin(z2/$target_neck_thickness);
		a0 = 90-angle_excess;
		a1 = 270+angle_excess;
		rotate([-90, 0, 0])
			if (len(target_neck_thickness_additional_points) < 1) {
				render() hull() {
					translate([0,0,neck_length-0.0001]) linear_extrude(0.0001)
						polygon([for (i = [0:300]) let(a=lerp(a0, a1, i/300.0)) [neck_width(neck_length)*0.5*sin(a), -$target_neck_thickness*cos(a)]]);  // Ellipse
					translate([0,0,0]) linear_extrude(0.0001)
						polygon([for (i = [0:300]) let(a=lerp(a0, a1, i/300.0)) [neck_width(0)*0.5*sin(a), -$target_neck_thickness*cos(a)]]);  // Ellipse
				}
			} else {
				pts = flatten([[[neck_length, $target_neck_thickness]], target_neck_thickness_additional_points]);
				echo(pts);
				for (i = [0:len(pts)-2]) {
					pt0 = pts[i];
					pt1 = pts[i+1];
					echo(i, pt0, pt1);
					render() hull() {
						translate([0,0,pt0[0]]) linear_extrude(0.01)
							polygon([for (i = [0:300]) let(a=lerp(a0, a1, i/300.0)) [neck_width*0.5*sin(a), -pt0[1]*cos(a)]]);  // Ellipse
						translate([0,0,pt1[0]]) linear_extrude(0.01)
							polygon([for (i = [0:300]) let(a=lerp(a0, a1, i/300.0)) [neck_width*0.5*sin(a), -pt1[1]*cos(a)]]);  // Ellipse
					}
				}
			}
		// Add any children to this so other functions will difference from the additions
		children();
	}
	module scallop(fret) {
			x0 = fret_scale_length(fret-1) - get_fret_width(fret-1)/2;
			x1 = fret_scale_length(fret) + get_fret_width(fret)/2;
			xmid = lerp(x0, x1, 0.5);
			xdelta = x0-x1;

			maxdepth_angle = 90+arc_points_angle([[x0, z1], [x1, z1], [xmid, z0]]);
			// echo(str(maxdepth_angle));
			a = min(max_scallop_angle, maxdepth_angle);
			fn = 50;
			fn2 = fn * 2;
			ca = cos(a);
			sa = sin(a);
			r = xdelta / (2*sa);
			arc = [ for (i = [-fn:fn]) [xmid+xdelta*i/fn2, z1-r*(sqrt(1 - ((sa*i/fn)^2))-ca)] ];
			// echo(arc);
			rotate([90, 0, 90]) linear_extrude($neck_width_bridge, center=true) polygon(arc);
	}
	module scallops() {
		for (fret = [0:$num_frets]) {
			scallop(fret);
		}
	}
	module fret_bump(fw, a = $fret_angle) {
		// a must be in range (0,90] for correct geometry
		fn = 50;
		fn2 = fn * 2;
		ca = cos(a);
		sa = sin(a);
		r = fw / (2*sa);
		arc = [ for (i = [-fn:fn]) [fw*i/fn2, r*(sqrt(1 - ((sa*i/fn)^2))-ca)] ];
		// echo("fret_bump", a, ca, arc);
		rotate([90, 0, 90]) linear_extrude($neck_width_bridge, center=true) polygon(arc);
	}
	module fret_bumps() {
		for (fret = [0:$num_frets])
			translate([0, fret_scale_length(fret), z1])
				fret_bump(get_fret_width(fret));
	}
	module intersect_fret_layers() {
		for (fret = [0:$num_frets]) {
			translate([-500, fret_scale_length(fret)-get_fret_width(fret)/2, -500])
				cube([1000, get_fret_width(fret), 1000]);
		}
		// Some precision error with fret 0 :/
		translate([-500, fret_scale_length(0)-get_fret_width(0)/2+0.0006, -500])
			cube([1000, get_fret_width(0), 1000]);
	}
	module fret_inlays() {
		for (num_text = fret_inlays) {
			fret = num_text[0];
			if (fret <= $num_frets) {
				x0 = fret_scale_length(fret-1)-get_fret_width(fret-1)/2;
				x1 = fret_scale_length(fret)+get_fret_width(fret)/2;
				x_mid = lerp(x0, x1, 0.5);
				max_height = x0 - x1 - 4;
				max_width = neck_width(x_mid) * 0.8;
				estimated_width_chars = len(num_text[1])*7/5;
				fontsize_from_max_width = max_width/estimated_width_chars;
				fontsize_from_max_height = max_height;
				// echo(str(max_width, "   ", estimated_width_chars, "   ", fontsize_from_max_height, "   ", fontsize_from_max_width));
				desired_fontsize = min(fontsize_from_max_height, fontsize_from_max_width);
				translate([0, x_mid, z0-0.5])
					linear_extrude(30)
					text(text = num_text[1], font = JP_Sans_Font, halign = "center", valign = "center", size = clamp(2, desired_fontsize, 10));
			}
		}
	}
	module fret_side_markers() {
		for (num_text = fret_inlays) {
			fret = num_text[0];
			if (fret <= $num_frets) {
				x0 = fret_scale_length(fret-1)-get_fret_width(fret-1)/2;
				x1 = fret_scale_length(fret)+get_fret_width(fret)/2;
				diff = x0 - x1;
				mid = lerp(x0, x1, 0.67);
				fontsize = min(5, diff*0.6);
				rotate([0, fret_side_marker_y_angle-90, 0])
					translate([0, mid, neck_width(mid)/2-3])
					linear_extrude(50)
					rotate(fret_side_marker_x_angle)
					text(text = str(fret), font = JP_Serif_Font, halign = "right", valign = "center", size = fontsize);
			}
		}
	}

	module carved_stock() {
		render() difference() {
			neck_stock() children();
			scallops();
			scallop($num_frets+1);
			// Chop off anything above the frets
			translate([-$neck_width_bridge, 0, z1]) cube([$neck_width_bridge*2, $guitar_scale_length_mm*3, $target_neck_thickness*3]);
			// Reduce rest of the body to 0
			translate([-$neck_width_bridge, 0, 0]) cube([$neck_width_bridge*2, (fret_scale_length($num_frets)+fret_scale_length($num_frets+1))/2, $target_neck_thickness*3]);
		}
		intersection() {
			fret_bumps();
			neck_stock();
		}
	}

	if (filler) {  // Somewhat placeholder for now
		difference() {
			neck_stock();
			scallop(25);
			translate([-$neck_width_bridge, 0, scallop_depth]) cube([$neck_width_bridge*2, $guitar_scale_length_mm*3, target_neck_thickness*3]);
			translate([-$neck_width_bridge, 0, 0]) cube([$neck_width_bridge*2, (fret_scale_length(25)+fret_scale_length(24))/2, target_neck_thickness*3]);
		}
	} else {
		has0 = list_has($include_colours, 0);
		has1 = list_has($include_colours, 1);
		has2 = list_has($include_colours, 2);
		has3 = list_has($include_colours, 3);
		if (has0) {
			render() difference() {
				carved_stock() children();
				if (!has1) intersect_fret_layers();
				if (!has2) fret_inlays();
				if (!has3) fret_side_markers();
			}
		} else render() intersection() {
			difference() {
				carved_stock() children();
				if (!has1) intersect_fret_layers();
				if (!has2) fret_inlays();
				if (!has3) fret_side_markers();
			}
			if (has1 || has2 || has3) union() {
				if (has1) intersect_fret_layers();
				if (has2) fret_inlays();
				if (has3) fret_side_markers();
			}
		}
	}
}