include <common.scad>
Guitar_Scale_Length_mm = 610;  // millimetres, slightly over 24inch (609.6mm) Jaguar scale, should be fine for guitar and u-bass
assert(fret_scale_length(0) == 610);  // Make sure the function correctly uses our changed global

CF_Tube_Dia = 5.0;
CF_Square_Width = 6.0;

// Philippians 4:8
// Gideon 真実な, 尊ぶべき, 正しい, 清い, 愛すべき, 評判の良い, 徳とされる, 称賛に値する
// ShinKaiYaku65 最後に、兄弟たち。すべての真実なこと、すべての誉れあること、すべての正しいこと、すべてのきよいこと、すべての愛すべきこと、すべての評判の良いこと、そのほか徳と言われること、称賛に値することがあるならば、そのようなことに心を留めなさい。
// I swapped 愛 and 評判 because 12th fret should be the biggest marker, and having only 15 as a 2char marker would be too disorienting
// going with 良 for 21
fret_inlays = [[3, "真"], [5, "尊"], [7, "正"], [9, "清"], [12, "評判"], [15, "愛"], [17, "徳"], [19, "賛"], [21, "良"], [24, "主イエス"]];



module neck(string_spacing=18, string_margin=5, num_strings=3, target_neck_thickness=15, scallop_depth=3, num_frets=24, fret_width=2.4) {
	neck_length = fret_scale_length(0)+fret_width/2;
	neck_width = (num_strings-1)*string_spacing + string_margin*2;
	// Could do some trig to work out exactly how much to add for the scallop depth, but we're subtracting anyway
	angle_excess = 20;
	module neck_stock() {
		rotate([-90, 0, 0])
			linear_extrude(neck_length)
			polygon([for (a = [90-angle_excess:1:270+angle_excess]) [neck_width*0.5*sin(a), -target_neck_thickness*cos(a)]]);
	}
	module scallops() {
		for (fret = [0:num_frets]) {
			x0 = fret_scale_length(fret-1) - fret_width/2;
			x1 = fret_scale_length(fret) + fret_width/2;
			xmid = lerp(x0, x1, 0.5);
			// Radius it?
			arc = arc_points([[x0, scallop_depth], [x1, scallop_depth], [xmid, 0]]);
			echo(arc);
			rotate([90, 0, 90]) linear_extrude(neck_width, center=true) polygon(arc);
		}
	}
	module fret_bumps() {
		for (fret = [0:num_frets]) {
			translate([0, fret_scale_length(fret), scallop_depth])
				rotate([0, 90]) cylinder(d=fret_width, h = neck_width, center = true, $fn=200);
		}
	}
	module fret_inlays() {
		for (num_text = fret_inlays) {
			fret = num_text[0];
			x0 = fret_scale_length(fret-1);
			x1 = fret_scale_length(fret);
			diff = x0 - x1;
			translate([0, lerp(x0, x1, 0.5), -0.5])
				linear_extrude(30)
				text(text = num_text[1], font = JP_Serif_Font, halign = "center", valign = "center", size = clamp(2, diff-fret_width*2-2, 10));
		}
	}
	module fret_side_markers() {
		for (num_text = fret_inlays) {
			fret = num_text[0];
			x0 = fret_scale_length(fret-1);
			x1 = fret_scale_length(fret);
			diff = x0 - x1;
			rotate([0, -90, 0])
				translate([0, x1, neck_width/2-3])
				linear_extrude(50)
				rotate(-35)
				text(text = str(fret), font = JP_Serif_Font, halign = "right", valign = "center", size = 5);
		}
	}
	// scallops();
	render() difference() {
		neck_stock();
		scallops();
		fret_inlays();
		fret_side_markers();
		translate([-neck_width, 0, scallop_depth]) cube([neck_width*2, Guitar_Scale_Length_mm*3, target_neck_thickness*3]);
	}
	intersection() {
		fret_bumps();
		neck_stock();
	}
}

module cf_tube(tolerance = 0.2) {
	rotate([-90,0,0])
	cylinder(h=Guitar_Scale_Length_mm+10, d=CF_Tube_Dia+tolerance, $fn=360);
}

module cf_square(tolerance = 0.2) {
	x = CF_Square_Width+tolerance;
	translate([-x/2, 0, -x/2])
	cube([x, Guitar_Scale_Length_mm+10, x]);
}

difference() {
	neck();
	for (i = [-1:2:1])
		translate([i*15, 0, -4])
		cf_tube();
	for (i = [-1:2:1])
		translate([i*7.5, 0, -7])
		cf_square();
	translate([0, 0, -10])
		cf_tube();

	echo(fret_scale_length(0) - fret_scale_length(8));  // 225.724
	echo(fret_scale_length(8) - fret_scale_length(24));  // 240.335
	segment_cut = fret_scale_length(24)-1.2;
	translate([-50, 0, -50]) cube([100, segment_cut, 100]);
	translate([-50, fret_scale_length(8)-1.2, -50]) cube([100, fret_scale_length(0), 100]);
	rotate([90, 0, 0]) linear_extrude((segment_cut+0.3)*2, center=true)  text(text = "01", font = JP_Serif_Font, halign = "center", valign = "center", size = 4);
}